kostenloser Webspace werbefrei: lima-city

mit BAT internetverbindung testen?

lima-city → Forum → Programmiersprachen → Sonstige Programmiersprachen

1. Autor dieses Themas

   w******e

   10:21, 25.1.2010

   Hiy.
   Wie kann ich mit einer BATCH-Datei testen, ob eine verbindung mit dem internet besteht?
   mit einem Ping?
   oder Netstat?
   
   greez

2. Diskutiere mit und stelle Fragen: Jetzt kostenlos anmelden!

   lima-city: Gratis werbefreier Webspace für deine eigene Homepage

3. karpfen

   

   karpfen hat kostenlosen Webspace.

   10:25, 25.1.2010

   Mit einem Ping auf eine externe IP kannst du das testen.
4. Autor dieses Themas

   w******e

   10:29, 25.1.2010

   Ja, aber wie kann ich das machen, dass bei einer verbindung angegebn wird, dass eine verbindung besteht?
   So dass der benutzer vom Ping nix mitkrigt?
   z.B.
   

   @ echo off
   ping www.google.com
   echo verbindung zum Internet besteht
   else echo Verbindung besteht nicht.

   
   
   Geht das so?
   
   Beitrag zuletzt geändert: 25.1.2010 10:34:16 von wireware

5. burgi

   Co-Admin

   burgi hat kostenlosen Webspace.

   11:10, 25.1.2010

   Der Gockel hat's wieder mal gefunden:
   http://www.techimo.com/forum/networking-internet/73769-handy-batch-file-check-network-connectivity.html
   
   Wie du allerdings siehst, ist das Batch-Script dann abhängig von der Betriebssystem-Sprache, und du musst das für Deutsch entsprechend abändern:
   
   

   @echo off
   ECHO Checking connection, please wait...
   PING -n 1 www.google.com|find "Antwort von  " >NUL
   IF NOT ERRORLEVEL 1 goto :SUCCESS
   IF     ERRORLEVEL 1 goto :TRYAGAIN
   
   :TRYAGAIN
   ECHO FAILURE!
   ECHO Let me try a bit more, please wait...
   @echo off
   PING -n 3 www.google.com|find "Antwort von " >NUL
   IF NOT ERRORLEVEL 1 goto :SUCCESS2
   IF     ERRORLEVEL 1 goto :TRYIP
   
   :TRYIP
   ECHO FAILURE!
   ECHO Checking DNS...
   ECHO Lets try by IP address...
   @echo off
   ping -n 1 216.239.37.99|find "Antwort von " >NUL
   IF NOT ERRORLEVEL 1 goto :SUCCESSDNS
   IF     ERRORLEVEL 1 goto :TRYROUTER
   
   :TRYROUTER
   ECHO FAILURE!
   ECHO Lets try pinging the router....
   ping -n 2 192.168.1.1|find "Antwort von " >NUL
   IF NOT ERRORLEVEL 1 goto :ROUTERSUCCESS
   IF     ERRORLEVEL 1 goto :NETDOWN
   
   :ROUTERSUCCESS
   ECHO It appears that you can reach the router, but internet is unreachable.
   goto :FAILURE
   
   :NETDOWN
   ECHO FAILURE!
   ECHO It appears that you having network issues, the router cannot be reached.
   goto :FAILURE
   
   :SUCCESSDNS
   ECHO It appears that you are having DNS issues.
   goto :FAILURE
   
   :SUCCESS
   ECHO You have an active Internet connection
   pause
   goto END
   
   :SUCCESS2
   ECHO You have an active internet connection but some packet loss was detected.
   pause
   goto :END
   
   :FAILURE
   ECHO You do not have an active Internet connection
   pause
   goto :END
   
   :END

6. Autor dieses Themas

   w******e

   11:12, 25.1.2010

   Danke passt genau ;)

7. t********g

   17:53, 26.1.2010

   Warum so viel geteste?
   
   for /F "tokens=2 Delims=:" %%i in ('ipconfig /all^|Find /i "IP-A"') do @Set IP=%%i
   if "%IP%"=="" echo Keine Verbindung
   
   Ab Vista:
   for /F "tokens=2 Delims=:" %%i in ('ipconfig^|Find /i "IPv4"') do @Set IP=%%i
   if "%IP%"=="" echo Keine Verbindung

8. dwow

   dwow hat kostenlosen Webspace.

   19:32, 26.1.2010

   danke tid. funzt perfekt dein script (auf xp)

9. Diskutiere mit und stelle Fragen: Jetzt kostenlos anmelden!

   lima-city: Gratis werbefreier Webspace für deine eigene Homepage

Dir gefällt dieses Thema?